flyinweb's blog

1、如何修改Subversion日志

我想用过Subversion的人一定有过这样的问题：“为什么不允许用户修改日志？”，因为这种改变不可还原（目前这个操作还没有受到版本控制的管理），所以这项功能默认是被禁止的。如果要开启它，必须设置一个pre-revprop-change钩子。

版本库生成后，hooks目录下就存在一些钩子脚本的模板，用户可以作为参考。这里我们可以把已经存在的pre-revprop-change.tmpl复制一份，将复制后的文件名改为pre-revprop-change.bat，钩子就设置好了。注意Windows下钩子脚本必须以.bat或者.exe的扩展名形式存在。

默认的钩子模板使用的是linux下的脚本语言，不能在Windows下运行。所以我们必须重写，这里介绍用批处理文件来写钩子脚本的方法。最简单的允许修改日志的pre-revprop-change.bat连一行都不需要，直接把pre-revprop-change.bat的内容清空就行了，因为按照Subversion的约定，钩子脚本返回0就是允许修改任何属性。

日志钩子脚本包括以下功能：
1、只允许用户修改自己的日志。可以设置超级用户，超级用户可以修改其他人的日志，其他人只能修改自己的日志。
2、只允许对日志进行操作，不允许对其它属性操作。
3、只允许对日志进行修改，不允许增加、删除日志。

脚本如下：

@ECHO OFF

REM 限制日志文件的个数采用修改项目属性的tsvn:logminsize，不在脚本中限制

REM 参数
set repos=%1
set rev=%2
set user=%3
set propname=%4
set action=%5

REM 设置超级用户，超级用户可以修改其他人的日志，其他人只能修改自己的日志
set superUser=ygq


REM 只允许日志svn:log的修改
if /I not '%propname%'=='svn:log' goto ERROR_PROPNAME


REM 只允许修改日志，增加、删除等操作不允许
if /I not '%action%'=='M' goto ERROR_ACTION


REM 只允许用户修改自己的日志
for /f "usebackq" %%k in (`svnlook author %repos% -r %rev%`) do @set var=%%k


set rightUser=0
if "%3" == "%superUser%" set rightUser=1
if "%3" == "%var%" set rightUser=1

if %rightUser% == 0 goto ERROR_USER

goto :SUCCESS_EXIT

:ERROR_USER
echo 只允许用户修改自己的日志 >&2
goto ERROR_EXIT


:ERROR_PROPNAME
echo 只有日志信息能被修改 >&2
goto ERROR_EXIT

:ERROR_ACTION
echo 只允许修改日志，不允许增加、删除等操作 >&2
goto ERROR_EXIT

:ERROR_EXIT
exit 1

:SUCCESS_EXIT
exit 0


使用：将以上脚本保存为pre-revprop-change.cmd或pre-revprop-change.bat，并放到版本库的hooks文件夹下。